ABBUC e.V. Forum

Code: Alles auswählen

; UWORD __fastcall__
; SM_Sqrt(ULONG lValue_);
; 
.define result sreg
.define input  ptr4
.define T      ptr1

.export _SM_Sqrt
.proc 	_SM_Sqrt

		sta input
		stx input+1
		lda sreg
		sta input+2
		lda sreg+1
		sta input+3

		lda #0
        sta result        ; R=0
        sta result+1
        sta input+4
        ;sta T+15        ; (T+1) is zero until last iteration; (T+0) is always 0
 
        clc
        ldy #14          ; 15 iterations (14-->0) + last iteration
loopsq:  
        lda result       ; (2*R+D) LSR 1; actually: R+(D LSR 1)
        ora stablo,y     ; using ORA instead of ADC is ok because the bit to be set
        sta T+2          ; will have not been affected yet
        lda result+1
        ora stabhi,y
        sta T+3
        bcs skip0      	 ; takes care of large numbers; if set, input>T
 
        lda input+3
        cmp T+3
        bcc skip1        ; T <= input    (branch if T>input)
        bne skip0
        lda input+2
        cmp T+2
        bcc skip1
skip0:  ;sec
        lda input+2      ; input=input-T
        sbc T+2
        sta input+2
        lda input+3
        sbc T+3
        sta input+3
        lda result       ; R=R+D
        ora stablo+1,y
        sta result
        lda result+1
        ora stabhi+1,y
        sta result+1
skip1:
        asl input       ; input=input*2
        rol input+1 
        rol input+2
        rol input+3
        dey             ; implicit: D=D/2, by the decrement of .Y
        bpl loopsq
lastiter:               ; code for last iteration
        bcs skp0        ; takes care of large numbers; if set, input>T
        				; during last iteration D=1, so [(2*R+D) LSR 1] makes D the MSB of T+1
        lda input+3
        cmp result+1    ; (T+3) = resultHI
        bcc skp1        ; T <= input    branch if T>input
        bne skp0
        lda input+2
        cmp result      ; (T+2) = resultLO
        bcc skp1
        bne skp0
        lda input+1
        cmp #$80        ; value of (T+1) during last iteration
        bcc skp1
skp0:
	    ;sec
        lda input+1
        sbc #$80        ; (T+1) during last iteration
        sta input+1
        lda input+2     ; input=input-T
        sbc result      ; (T+2)
        sta input+2
        lda input+3
        sbc result+1    ; (T+3)
        sta input+3
        inc result      ; R=R+D with D=1
skp1:   
        lda result
        ldx result+1
        rts

.endproc

.data 
stabhi: .byte 0,0,0,0,0,0,0,0
stablo: .byte $01,$02,$04,$08,$10,$20,$40,$80
        .byte 0,0,0,0,0,0,0,0

Code: Alles auswählen

public int sqrt(int WurzelAus) {
  int Wert;
  int nextWert = (WurzelAus + 1) / 2;
  do {
    Wert = nextWert;
    nextWert = (Wert + (WurzelAus / Wert)) / 2;
  } while (nextWert != Wert);
  return Wert;
}

Code: Alles auswählen

5	Graphics 0
10	Input A
20	B=1
30	C=A
40	For F=1 To 6
50	C=C+B
60	C=C/2
70	B=A/C
80	Next F
90	Print C

Code: Alles auswählen

			 .proc qwurzel	;von var1
			 ldx #0
			 ldy #6
			 lda var1
			 sta var3
			 lda #1
			 sta var2
	lp1
			clc
			lda var3
			adc var2
			sta var3
			lsr var3
			lda var1
			;------------ hier Divisionsroutine
			ldx #255
			sec
	lp2		
			sbc var3
			inx
			bcs lp2
			stx var2
			;----------- Division Ende
			dey
			bpl lp1
			rts
			.endp

Code: Alles auswählen

   LDA #0
   STA ROOT
   STA REM
   LDX #8
L1 SEC
   LDA NUMH
   SBC #$40
   TAY
   LDA REM
   SBC ROOT
   BCC L2
   STY NUMH
   STA REM
L2 ROL ROOT
   ASL NUML
   ROL NUMH
   ROL REM
   ASL NUML
   ROL NUMH
   ROL REM
   DEX
   BNE L1
 

Code: Alles auswählen

		.proc qwurzel16bit
		; Quadratwurzel 16 Bit
		; nach Lee Davison
		; Quadratwurzel var1/var1+1
		
		lda #0
		sta var2
		sta var3
		ldx #8
lp1
		sec
		lda var1+1
		sbc #64
		tay
		lda var3
		sbc var2
		bcc lp2
		sty var1+1
		sta var3
lp2
		rol var2
		asl var1
		rol var1+1
		rol var3
		asl var1
		rol var1+1
		rol var3
		dex
		bne lp1
		rts
		.endp