stereoskopisches Bild

[Dr. Irata]

Guten Morgen!
Hat hier irgendjemand ein Bild - z.B. in einer guten 4kb Atari-Auflösung - welches stereoskopisch aufgenommen wurde?
Also quasi 2 Bilder, die leicht versetzt aufgenommen wurden und jeweils in einem Format vorliegen, was man in das Atari-Display einladen kann.
Gruß
Peter

[Andars]

Hallo,

ich habe einen Bekannten, der hier mit liest, aber nicht antworten kann.
Er ist hier leider nicht angemeldet. Also tue ich es in seinem Namen.

Hier ein Beispielbild:



Er wäre auch an einem E-Mailkontakt interessiert.

Gruß
Andreas

[Dr. Irata]

Hallo Andreas,
vielen Dank für das Bild - bzw. die Bilder. Wenn man entsprechend beide Bilder mit einem Blatt in der Mitte visiert, sieht man den 3D-Effekt. Gruß an deinen Bekannten!!
Jetzt brauche ich das Bild nur noch irgendwie in Atari-Format konvertiert... hat irgendjemand eine Möglichkeit das zu konvertieren??
Auflösung ist eigentlich egal, wünschenswert wäre relativ hoch aufgelöst... so auf 4kB z.B.
Darüber wäre ich echt dankbar!
Gruß
Peter

[Sleeπ]

Für den Atari wäre aber vermutlich ein einfacheres Bild mit nicht so vielen Details besser. Wenn man das obige Bild auf ATARI runterskaliert, bleibt wohl nicht viel erkennbares über. Wenn der Bekannte solche Fotos selber machen kann, würde ich einmal mit einfacheren Sachen anfangen, vielleicht drei einfache Objekte vor neutralem Hintergrund.

[Dr. Irata]

Ok - dann die Frage an den Bekannten - gerne auch Austausch via Mail - ob er so ein Bild machen kann mit 3-4 einfarbigen Objekten und einem einfarbigen Hintergrund... sagen wir mal mit maximal 4 Farben zunächst!
Das wäre richtig cool!!

[Dr. Irata]

btw... der Rubik Cube im Hintergrund... sehr cool!!

[Andars]

Hier noch 2 Teilbilder von Thomas Rademacher:

[Irgendwer]

stereo.gif (8.06 KiB) 1683 mal betrachtet

Bilder kann man gut mit dem "Atari Graphics Studio" konvertieren (https://g2f.atari8.info/).

An die Forum-Admins:
Ich hätte gerne das ".mic" und ".g2f" hier direkt als Anhang angefügt - die Extension wird aber abgelehnt.
Vielleicht kann man das ändern?

[Dr. Irata]

Hallöle... ich konnte das .mic jetzt laden und darstellen.
Leider habe ich noch eine falsche Farbtabelle drin und ich bräuchte für meinen "Test" beide Bilder in 2 .mic Dateien!
Gruß
Peter

[Irgendwer]

...kannst ja mal versuchen ob Du mit den 2 angehängten Bildern im Archiv was anfangen kannst (anderes Foto, L und R getrennt).

[atarixle]

stereo.gif

Bilder kann man gut mit dem "Atari Graphics Studio" konvertieren (https://g2f.atari8.info/).

An die Forum-Admins:
Ich hätte gerne das ".mic" und ".g2f" hier direkt als Anhang angefügt - die Extension wird aber abgelehnt.
Vielleicht kann man das ändern?

Bei diesen Bildern sehe ich gleich das Problem, dass es sich hierbei nun mal um zwei unterschiedliche Aufnahmen handelt und sich neben der Perspektive auch die Belichtung geändert hat.
Bei der Konvertierung auf 4 Farben führt dies zu sehr unterschiedlich großen Anteilen der resultierenden Grauwerte. Abgesehen davon hat das Einzelbild nur noch eine Auflösung von 80x192 Pixeln, hier gehen zu viele Details verloren, um noch einen stereoskopischen Effekt zu erzeugen.

Ich selber würde für Experimente mit 3D-Bildern ein auf dem Atari erzeugtes Vektor-Bild in Graphics 8 setzen. Das bekommt man in BASIC leicht hin.

[atarixle]

CUBE3D.BAS

Code: Alles auswählen

100 GRAPHICS 8+16:SETCOLOR 1,0,0:SETCOLOR 2,0,15:SETCOLOR 4,0,15:COLOR 1
110 DIM CUBE(256)
120 I=-4
130 READ C,X,Y,Z:I=I+4
140 IF C=999 THEN 160
145 X=X+X-1:Y=Y+Y-1:Z=-Z-Z+1
150 CUBE(I)=C:CUBE(I+1)=X:CUBE(I+2)=Y:CUBE(I+3)=Z:GOTO 130
160 REM SZ = size; ps = perspective
161 REM DI = distance
162 REM df = difference left/right
165 SZ=50:PS=1.1:DI=3:DF=0.1
190 FOR LR=-1 TO 1 STEP 2
200   FOR D=0 TO I-1 STEP 4
210     C=CUBE(D):X=CUBE(D+1)-LR*DF:Y=CUBE(D+2):Z=CUBE(D+3)
220     DX=X*SZ/(Z+DI)*PS+160+LR*80
225     DY=Y*SZ/(Z+DI)*PS+96
230     ON C GOTO 240,250
240     PLOT DX,DY:GOTO 260
250     DRAWTO DX,DY
260   NEXT D
270 NEXT LR
490 IF PEEK(764)=255 THEN 490
499 POKE 764,255:END 
5000 DATA 1,0,0,0
5010 DATA 2,0,1,0
5020 DATA 2,0,1,1
5030 DATA 2,1,1,1
5040 DATA 2,1,0,1
5050 DATA 2,1,0,0
5060 DATA 2,0,0,0
5070 DATA 2,0,0,1
5080 DATA 2,1,0,1
5090 DATA 1,0,1,0
5100 DATA 2,1,1,0
5110 DATA 2,1,0,0
5120 DATA 1,1,1,0
5130 DATA 2,1,1,1
5140 DATA 1,0,1,1
5150 DATA 2,0,0,1
5160 DATA 999,999,999,999

... und wer richtig Bock drauf hat, lässt das Objekt noch rotieren.

[atarixle]

... gern geschehen:

Code: Alles auswählen

99 DEG 
100 GRAPHICS 8+16:DL1L=PEEK(560):DL1H=PEEK(561):PST1L=PEEK(88):PST1H=PEEK(89)
101 TOP=PEEK(106)
102 POKE 106,TOP-32
103 GRAPHICS 8+16:DL2L=PEEK(560):DL2H=PEEK(561):PST2L=PEEK(88):PST2H=PEEK(89)
104 POKE 106,TOP:SCR=0
105 SETCOLOR 2,0,15:SETCOLOR 4,0,15:SETCOLOR 1,0,0:COLOR 1
110 DIM CUBE(256)
120 I=-4:RX=0:RY=0:RZ=0
130 READ C,X,Y,Z:I=I+4
140 IF C=999 THEN 160
145 X=X+X-1:Y=Y+Y-1:Z=-Z-Z+1
150 CUBE(I)=C:CUBE(I+1)=X:CUBE(I+2)=Y:CUBE(I+3)=Z:GOTO 130
160 REM SZ = size; ps = perspective
161 REM DI = distance
162 REM df = difference left/right
165 SZ=100:PS=1.1:DI=6:DF=0.1
170 IF SCR=0 THEN POKE 88,PST2L:POKE 89,PST2H:POKE 560,DL1L:POKE 561,DL1H:SCR=1:POKE 106,TOP-32:GOTO 180
171 POKE 88,PST1L:POKE 89,PST1H:POKE 560,DL2L:POKE 561,DL2H:SCR=0:POKE 106,TOP
180 COLOR ASC("{ESC Ctrl+<}"):PLOT 0,0:COLOR 1:POKE 106,TOP
185 CO=COS(RY):SI=SIN(RY)
190 FOR LR=-1 TO 1 STEP 2
200   FOR D=0 TO I-1 STEP 4
210     C=CUBE(D):X=CUBE(D+1):Y=CUBE(D+2):Z=CUBE(D+3)
212     X2=CO*X+SI*Z-LR*DF:Y2=Y:Z2=-SI*X+CO*Z
220     DX=X2*SZ/(Z2+DI)*PS+160+LR*80
225     DY=Y2*SZ/(Z2+DI)*PS+96
230     ON C GOTO 240,250
240     PLOT DX,DY:GOTO 260
250     DRAWTO DX,DY
260   NEXT D
270 NEXT LR
280 RY=RY+1:POKE 77,0
490 IF PEEK(764)=255 THEN 170
499 POKE 764,255:END 
5000 DATA 1,0,0,0
5010 DATA 2,0,1,0
5020 DATA 2,0,1,1
5030 DATA 2,1,1,1
5040 DATA 2,1,0,1
5050 DATA 2,1,0,0
5060 DATA 2,0,0,0
5070 DATA 2,0,0,1
5080 DATA 2,1,0,1
5090 DATA 1,0,1,0
5100 DATA 2,1,1,0
5110 DATA 2,1,0,0
5120 DATA 1,1,1,0
5130 DATA 2,1,1,1
5140 DATA 1,0,1,1
5150 DATA 2,0,0,1
5160 DATA 999,999,999,999

(bitte das Programm nicht mit BREAK verlassen, sondern irgend einer anderen Taste)

[Dr. Irata]

das ist wirklich gut... leider so langsam

[atarixle]

BASIC halt.

Das Programm läuft in Atari-BASIC und auch Turbo-BASIC. Es sollte sich eigentlich auch kompilieren lassen.

Man könnte auch noch die verdeckten Kanten weglassen und die Drehung mit 90° simulieren.

Auch könnte man den SIN von 0° bis 90° vorausberechnen.

Man könnte auch Graphics 6 nutzen, das ist wesentlich schneller - hat aber sehr wenig Auflösung, so dass ich eher befürchte, die Details würden zu wenig, um noch stereoskopisch zu wirken.